module Collision ( collisionTankBorder
                 , collisionBulletBullet
                 ) where

import Tank
import Game

import Data.Fixed
import Data.Ratio

tankWidth :: Micro
tankWidth = 0.95

tankLength :: Micro
tankLength = 0.95

bulletDiameter :: Micro
bulletDiameter = 0.1

collisionTankBorder :: Micro -> Micro -> Tank -> Tank
collisionTankBorder lw lh tank = tank {tankX = newx, tankY = newy}
    where
      dir = (fromRational . toRational . tankDir $ tank)*pi/180
      cosd = fromRational (round ((cos dir)*1000000)%1000000)
      sind = fromRational (round ((sin dir)*1000000)%1000000)
      
      points = [ (tankLength/2, tankWidth/2)
               , (-tankLength/2, tankWidth/2)
               , (-tankLength/2, -tankWidth/2)
               , (tankLength/2, -tankWidth/2)
               ]
      
      rotp (x, y) = (cosd*x - sind*y, sind*x + cosd*y)
      transp (x, y) = (x + tankX tank, y + tankY tank)
      
      pointst = map (transp . rotp) points
      minx = minimum $ map fst pointst
      maxx = maximum $ map fst pointst
      miny = minimum $ map snd pointst
      maxy = maximum $ map snd pointst
      
      dx = if minx < 0 then (-minx) else if maxx > lw then (-maxx+lw) else 0
      dy = if miny < 0 then (-miny) else if maxy > lh then (-maxy+lh) else 0
      
      newx = (tankX tank) + dx
      newy = (tankY tank) + dy

collisionBulletBullet :: (Bullet, Bullet) -> (Bullet, Bullet) -> Bool
collisionBulletBullet (b1, b1') (b2, b2') = distancesq < (bulletDiameter^2)
    where
      distancesq = (bulletX b1' - bulletX b2')^2 + (bulletY b1' - bulletY b2')^2