import XMonad
import XMonad.Config.Desktop
import XMonad.Actions.CycleWS
import XMonad.Actions.NoBorders
import XMonad.Actions.PhysicalScreens
import XMonad.Actions.Warp
import XMonad.Hooks.ManageDocks
import XMonad.Hooks.ManageHelpers
import XMonad.Hooks.SetWMName
import XMonad.Layout.ResizableTile
import qualified XMonad.StackSet as W
import XMonad.Util.EZConfig

import Control.Monad
import Control.Monad.Trans
import Data.Maybe
import Data.Monoid
import Ratio((%))
import System.Exit

--import ConfigurableBorders
import DynamicPerScreenWorkspaces
import EwmhDesktops
import FullscreenManager
import NoBorders
import ProcessWorkspaces


modm = mod4Mask

main = xmonad $ ewmh $ defaultConfig
       { modMask = modm
       , manageHook = myManageHook
       , layoutHook = desktopLayoutModifiers myLayoutHook
       , startupHook = myStartupHook
       , handleEventHook = myEventHook
       , workspaces = myWorkspaces
       , borderWidth = 0
       , logHook = ewmhDesktopsLogHook
       }
       `additionalKeysP` (
       [ ("M-a", sendMessage MirrorShrink)
       , ("M-y", sendMessage MirrorExpand)
       , ("M-<Left>",    prevWS)
       , ("M-<Right>",   nextWS)
       , ("M-S-<Left>",  shiftToPrev)
       , ("M-S-<Right>", shiftToNext)
       , ("M-S-b", withFocused toggleBorder >> refresh)
       , ("M-<F1>", viewOrWarp 0)
       , ("M-<F2>", viewOrWarp 1)
       , ("M-<F3>", viewOrWarp 2)
       , ("M-b", banishScreen LowerRight)
       , ("M-p", spawnOnCurrent "exe=`dmenu_path | /home/neoraider/bin/dmemu -b` && eval \"exec $exe\"")
       , ("M-g", gets (W.currentTag . windowset) >>= regroupProcess)
       , ("M-S-q", io (exitWith ExitSuccess))
       , ("C-M1-l", spawn "gnome-screensaver-command --lock")
       , ("M-`", spawn "xclip -o | qrencode -s 10 -o- | display -geometry +0+0")
       , ("M1-<F4>", kill)
       ]
       ++ [ (("M-" ++ show n, windows $ W.greedyView ws)) | (ws, n) <- zip myWorkspaces ([1..9]++[0])]
       ++ [ (("M-S-" ++ show n, shiftGroup ws)) | (ws, n) <- zip myWorkspaces ([1..9]++[0])]
       ++ [ (("M-C-" ++ show n, shiftIgnoreGroup ws)) | (ws, n) <- zip myWorkspaces ([1..9]++[0])]
       )
       `additionalMouseBindings`
       [ ((modm, button4), \_ -> sendMessage Shrink)
       , ((modm, button5), \_ -> sendMessage Expand)
       , ((modm .|. shiftMask, button4), \_ -> sendMessage MirrorExpand)
       , ((modm .|. shiftMask, button5), \_ -> sendMessage MirrorShrink)
       ]


myWorkspaces = map (show . flip mod 10) [1..10]


viewOrWarp :: Int -> X ()
viewOrWarp n = do
  wset <- gets windowset
  i <- getScreen $ P n
  whenJust i $ \s -> do
                 ws <- screenWorkspace s
                 whenJust ws $ \w -> windows . W.view $ w
                 when (s == (W.screen . W.current $ wset)) $ warpToScreen s (1%2) (1%2)


--myStartupHook :: X ()
--myStartupHook = do
--  startupHook gnomeConfig
--  spawn "killall -u `id -un` -q xcompmgr; exec xcompmgr"


setFullscreenSupported :: X ()
setFullscreenSupported = withDisplay $ \dpy -> do
  r <- asks theRoot
  a <- getAtom "_NET_SUPPORTED"
  c <- getAtom "ATOM"
  f <- getAtom "_NET_WM_STATE_FULLSCREEN"
  io $ changeProperty32 dpy r a c propModeAppend [fromIntegral f]



myStartupHook :: X ()
myStartupHook = do
  startupHook desktopConfig
  setWMName "LG3D"
  setFullscreenSupported
  spawn "ibus-daemon -r -x"

isUtility :: Query Bool
isUtility = isInProperty "_NET_WM_WINDOW_TYPE" "_NET_WM_WINDOW_TYPE_UTILITY"

moveToBottom :: ManageHook
moveToBottom = doF $ \windowSet@W.StackSet {W.current = screen@W.Screen {W.workspace = ws@W.Workspace {W.stack = windowStack}}} ->
  let windowStack' = fmap (\(W.Stack f u d) -> W.Stack f (reverse d ++ u) []) windowStack
  in windowSet { W.current = screen {W.workspace = ws {W.stack = windowStack'}} }
    
    

myManageHook :: ManageHook
myManageHook = composeAll
               [ moveToBottom
               , isDialog --> doFloat
               , composeOne
                 [ className =? "Guake.py"   -?> doFloatMaybeFullscreen -- <+> doConfigBorderOff)
                 --, className =? "Do"         -?> (doFloat <+> doConfigBorderOff)
                 , className =? "MPlayer"    -?> doCenterFloat
                 , className =? "Gnome-session" -?> doIgnoreProcessWorkspace
                 , className =? "Gimp"       -?> doFloat
                 , className =? "jrummikub-JRummikub" -?> doFloat
                 , className =? "Stjerm"     -?> doFloatMaybeFullscreen
                 , className =? "Display"    -?> doFloat
                 , className =? "Wine"       -?> doFloat
                 , className =? "Pcsx2"      -?> doFloat
                 , stringProperty "WM_ICON_NAME" =? "ZeroGS" -?> doFloat
                 , isFullscreen              -?> doFullscreen
                 ]
               , isUtility =? False --> doAutoShift
               , manageHook desktopConfig
               ]
        

myLayoutHook = processWorkspaceManager $ manageFullscreen $ smartBorders (Full ||| tiled ||| Mirror tiled)
  where
    -- default tiling algorithm partitions the screen into two panes
    tiled   = ResizableTall nmaster delta ratio []
 
    -- The default number of windows in the master pane
    nmaster = 1
 
    -- Default proportion of screen occupied by master pane
    ratio   = 3/5 

    -- Percent of screen to increment by when resizing panes
    delta   = 3/100

myEventHook :: Event -> X All
myEventHook ev = do
  handleForgetEmptyWindowGroups ev
  handleFullscreen ev
  handleEventHook defaultConfig ev