blob: 2424749fdc09c9c0f45c646852fca84749a8208a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
|
/*
* BIRD -- Configuration Parser Top
*
* (c) 1998--1999 Martin Mares <mj@ucw.cz>
*
* Can be freely distributed and used under the terms of the GNU GPL.
*/
CF_HDR
#include "nest/bird.h"
#include "conf/conf.h"
#include "lib/resource.h"
#include "lib/socket.h"
#include "lib/timer.h"
#include "nest/protocol.h"
#include "nest/iface.h"
#include "nest/route.h"
#include "nest/cli.h"
#include "filter/filter.h"
/* FIXME: Turn on YYERROR_VERBOSE and work around lots of bison bugs? */
CF_DECLS
%union {
int i;
u32 i32;
ip_addr a;
struct symbol *s;
char *t;
struct rtable_config *r;
struct f_inst *x;
struct filter *f;
struct f_tree *e;
struct f_val v;
struct password_item *p;
struct rt_show_data *ra;
void *g;
}
%token END CLI_MARKER
%token <i> NUM ENUM
%token <i32> RTRID
%token <a> IPA
%token <s> SYM
%token <t> TEXT
%type <i> expr bool pxlen datetime
%nonassoc '=' '<' '>' '~' '.'
%left '+' '-'
%left '*' '/' '%'
%left '!'
CF_KEYWORDS(DEFINE, ON, OFF, YES, NO)
CF_GRAMMAR
/* Basic config file structure */
config: conf_entries END { return 0; }
| CLI_MARKER cli_cmd { return 0; }
;
conf_entries:
/* EMPTY */
| conf_entries conf
;
CF_ADDTO(conf, ';')
/* Constant expressions */
expr:
NUM
| expr '+' expr { $$ = $1 + $3; }
| expr '-' expr { $$ = $1 - $3; }
| expr '*' expr { $$ = $1 * $3; }
| expr '/' expr { if ($3) $$ = $1 / $3; else cf_error("Division by zero"); }
| expr '%' expr { if ($3) $$ = $1 % $3; else cf_error("Division by zero"); }
| '(' expr ')' { $$ = $2; }
| SYM { if ($1->class != SYM_NUMBER) cf_error("Number expected"); else $$ = $1->aux; }
;
CF_ADDTO(conf, definition)
definition:
DEFINE SYM '=' expr ';' {
cf_define_symbol($2, SYM_NUMBER, NULL);
$2->aux = $4;
}
;
/* Switches */
bool:
expr {$$ = !!$1; }
| ON { $$ = 1; }
| YES { $$ = 1; }
| OFF { $$ = 0; }
| NO { $$ = 0; }
| /* Silence means agreement */ { $$ = 1; }
;
/* Prefixes and netmasks */
pxlen:
'/' NUM {
if ($2 < 0 || $2 > 32) cf_error("Invalid prefix length %d", $2);
$$ = $2;
}
| ':' IPA {
$$ = ipa_mklen($2);
if ($$ < 0) cf_error("Invalid netmask %I", $2);
}
;
datetime: /* Return seconds from epoch, FIXME we want be more user friendly */
NUM { $$ = $1; }
;
CF_CODE
CF_END
|
