Put together cmake build

10 files changed, 479 insertions, 0 deletions

diff --git a/.gitignore b/.gitignore
new file mode 100644
index 0000000..06c72ff
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,3 @@
+*~
+*.c
+build
diff --git a/CMakeLists.txt b/CMakeLists.txt
new file mode 100644
index 0000000..9dddf9a
--- /dev/null
+++ b/CMakeLists.txt
@@ -0,0 +1,21 @@
+project("eva" C)
+cmake_minimum_required(VERSION 2.6)
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/vala)
+
+include(ValaPrecompile)
+include(ValaVersion)
+
+find_package(Vala REQUIRED)
+ensure_vala_version("0.8" MINIMUM)
+
+
+find_package(PkgConfig)
+pkg_check_modules(GEE REQUIRED gee-1.0)
+pkg_check_modules(ERL REQUIRED erl_interface)
+
+add_definitions(${GEE_CFLAGS} ${GEE_CFLAGS_OTHER} ${ERL_CFLAGS} ${ERL_CFLAGS_OTHER})
+link_libraries(${GEE_LIBRARIES} ${ERL_LIBRARIES})
+link_directories(${GEE_LIBRARY_DIRS} ${ERL_LIBRARY_DIRS})
+
+add_subdirectory(src)
+add_subdirectory(test)
diff --git a/cmake/vala/FindVala.cmake b/cmake/vala/FindVala.cmake
new file mode 100644
index 0000000..50f1aed
--- /dev/null
+++ b/cmake/vala/FindVala.cmake
@@ -0,0 +1,65 @@
+##
+# Copyright 2009 Jakob Westhoff. All rights reserved.
+# 
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are met:
+# 
+#    1. Redistributions of source code must retain the above copyright notice,
+#       this list of conditions and the following disclaimer.
+# 
+#    2. Redistributions in binary form must reproduce the above copyright notice,
+#       this list of conditions and the following disclaimer in the documentation
+#       and/or other materials provided with the distribution.
+# 
+# THIS SOFTWARE IS PROVIDED BY JAKOB WESTHOFF ``AS IS'' AND ANY EXPRESS OR
+# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
+# MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO
+# EVENT SHALL JAKOB WESTHOFF OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+# PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+# LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE
+# OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+# 
+# The views and conclusions contained in the software and documentation are those
+# of the authors and should not be interpreted as representing official policies,
+# either expressed or implied, of Jakob Westhoff
+##
+
+##
+# Find module for the Vala compiler (valac)
+#
+# This module determines wheter a Vala compiler is installed on the current
+# system and where its executable is.
+#
+# Call the module using "find_package(Vala) from within your CMakeLists.txt.
+#
+# The following variables will be set after an invocation:
+#
+#  VALA_FOUND       Whether the vala compiler has been found or not
+#  VALA_EXECUTABLE  Full path to the valac executable if it has been found
+#  VALA_VERSION     Version number of the available valac
+##
+
+
+# Search for the valac executable in the usual system paths.
+find_program(VALA_EXECUTABLE
+  NAMES valac)
+
+# Handle the QUIETLY and REQUIRED arguments, which may be given to the find call.
+# Furthermore set VALA_FOUND to TRUE if Vala has been found (aka.
+# VALA_EXECUTABLE is set)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Vala DEFAULT_MSG VALA_EXECUTABLE)
+
+mark_as_advanced(VALA_EXECUTABLE)
+
+# Determine the valac version
+if(VALA_FOUND)
+    execute_process(COMMAND ${VALA_EXECUTABLE} "--version" 
+                    OUTPUT_VARIABLE "VALA_VERSION")
+    string(REPLACE "Vala" "" "VALA_VERSION" ${VALA_VERSION})
+    string(STRIP ${VALA_VERSION} "VALA_VERSION")
+endif(VALA_FOUND)
diff --git a/cmake/vala/ParseArguments.cmake b/cmake/vala/ParseArguments.cmake
new file mode 100644
index 0000000..717c0f5
--- /dev/null
+++ b/cmake/vala/ParseArguments.cmake
@@ -0,0 +1,36 @@
+##
+# This is a helper Macro to parse optional arguments in Macros/Functions
+# It has been taken from the public CMake wiki.  
+# See http://www.cmake.org/Wiki/CMakeMacroParseArguments for documentation and
+# licensing.
+##
+macro(parse_arguments prefix arg_names option_names)
+  set(DEFAULT_ARGS)
+  foreach(arg_name ${arg_names})
+    set(${prefix}_${arg_name})
+  endforeach(arg_name)
+  foreach(option ${option_names})
+    set(${prefix}_${option} FALSE)
+  endforeach(option)
+
+  set(current_arg_name DEFAULT_ARGS)
+  set(current_arg_list)
+  foreach(arg ${ARGN})
+    set(larg_names ${arg_names})
+    list(FIND larg_names "${arg}" is_arg_name)
+    if(is_arg_name GREATER -1)
+      set(${prefix}_${current_arg_name} ${current_arg_list})
+      set(current_arg_name ${arg})
+      set(current_arg_list)
+    else(is_arg_name GREATER -1)
+      set(loption_names ${option_names})
+      list(FIND loption_names "${arg}" is_option)
+      if(is_option GREATER -1)
+	    set(${prefix}_${arg} TRUE)
+      else(is_option GREATER -1)
+	    set(current_arg_list ${current_arg_list} ${arg})
+      endif(is_option GREATER -1)
+    endif(is_arg_name GREATER -1)
+  endforeach(arg)
+  set(${prefix}_${current_arg_name} ${current_arg_list})
+endmacro(parse_arguments)
diff --git a/cmake/vala/ValaPrecompile.cmake b/cmake/vala/ValaPrecompile.cmake
new file mode 100644
index 0000000..f69a096
--- /dev/null
+++ b/cmake/vala/ValaPrecompile.cmake
@@ -0,0 +1,156 @@
+##
+# Copyright 2009 Jakob Westhoff. All rights reserved.
+# 
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are met:
+# 
+#    1. Redistributions of source code must retain the above copyright notice,
+#       this list of conditions and the following disclaimer.
+# 
+#    2. Redistributions in binary form must reproduce the above copyright notice,
+#       this list of conditions and the following disclaimer in the documentation
+#       and/or other materials provided with the distribution.
+# 
+# THIS SOFTWARE IS PROVIDED BY JAKOB WESTHOFF ``AS IS'' AND ANY EXPRESS OR
+# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
+# MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO
+# EVENT SHALL JAKOB WESTHOFF OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+# PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+# LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE
+# OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+# 
+# The views and conclusions contained in the software and documentation are those
+# of the authors and should not be interpreted as representing official policies,
+# either expressed or implied, of Jakob Westhoff
+##
+
+include(ParseArguments)
+find_package(Vala REQUIRED)
+
+##
+# Compile vala files to their c equivalents for further processing. 
+#
+# The "vala_precompile" macro takes care of calling the valac executable on the
+# given source to produce c files which can then be processed further using
+# default cmake functions.
+# 
+# The first parameter provided is a variable, which will be filled with a list
+# of c files outputted by the vala compiler. This list can than be used in
+# conjuction with functions like "add_executable" or others to create the
+# neccessary compile rules with CMake.
+# 
+# The initial variable is followed by a list of .vala files to be compiled.
+# Please take care to add every vala file belonging to the currently compiled
+# project or library as Vala will otherwise not be able to resolve all
+# dependencies.
+# 
+# The following sections may be specified afterwards to provide certain options
+# to the vala compiler:
+# 
+# PACKAGES
+#   A list of vala packages/libraries to be used during the compile cycle. The
+#   package names are exactly the same, as they would be passed to the valac
+#   "--pkg=" option.
+# 
+# OPTIONS
+#   A list of optional options to be passed to the valac executable. This can be
+#   used to pass "--thread" for example to enable multi-threading support.
+#
+# CUSTOM_VAPIS
+#   A list of custom vapi files to be included for compilation. This can be
+#   useful to include freshly created vala libraries without having to install
+#   them in the system.
+#
+# GENERATE_VAPI
+#   Pass all the needed flags to the compiler to create an internal vapi for
+#   the compiled library. The provided name will be used for this and a
+#   <provided_name>.vapi file will be created.
+# 
+# GENERATE_HEADER
+#   Let the compiler generate a header file for the compiled code. There will
+#   be a header file as well as an internal header file being generated called
+#   <provided_name>.h and <provided_name>_internal.h
+#
+# The following call is a simple example to the vala_precompile macro showing
+# an example to every of the optional sections:
+#
+#   vala_precompile(VALA_C
+#       source1.vala
+#       source2.vala
+#       source3.vala
+#   PACKAGES
+#       gtk+-2.0
+#       gio-1.0
+#       posix
+#   OPTIONS
+#       --thread
+#   CUSTOM_VAPIS
+#       some_vapi.vapi
+#   GENERATE_VAPI
+#       myvapi
+#   GENERATE_HEADER
+#       myheader
+#   )
+#
+# Most important is the variable VALA_C which will contain all the generated c
+# file names after the call.
+##
+
+macro(vala_precompile output)
+    include_directories(${CMAKE_CURRENT_BINARY_DIR})
+    parse_arguments(ARGS "PACKAGES;OPTIONS;GENERATE_HEADER;GENERATE_VAPI;CUSTOM_VAPIS" "" ${ARGN})
+    set(vala_pkg_opts "")
+    foreach(pkg ${ARGS_PACKAGES})
+        list(APPEND vala_pkg_opts "--pkg=${pkg}")
+    endforeach(pkg ${ARGS_PACKAGES})
+    set(in_files "")
+    set(out_files "")
+    set(${output} "")
+    foreach(src ${ARGS_DEFAULT_ARGS})
+        list(APPEND in_files "${CMAKE_CURRENT_SOURCE_DIR}/${src}")
+        string(REPLACE ".vala" ".c" src ${src})
+        set(out_file "${CMAKE_CURRENT_BINARY_DIR}/${src}")
+        list(APPEND out_files "${CMAKE_CURRENT_BINARY_DIR}/${src}")
+        list(APPEND ${output} ${out_file})
+    endforeach(src ${ARGS_DEFAULT_ARGS})
+
+    set(vapi_arguments "")
+    if(ARGS_GENERATE_VAPI)
+        list(APPEND out_files "${CMAKE_CURRENT_BINARY_DIR}/${ARGS_GENERATE_VAPI}.vapi")
+        set(vapi_arguments "--internal-vapi=${ARGS_GENERATE_VAPI}.vapi")
+
+        # Header and internal header is needed to generate internal vapi
+        if (NOT ARGS_GENERATE_HEADER)
+            set(ARGS_GENERATE_HEADER ${ARGS_GENERATE_VAPI})
+        endif(NOT ARGS_GENERATE_HEADER)
+    endif(ARGS_GENERATE_VAPI)
+
+    set(header_arguments "")
+    if(ARGS_GENERATE_HEADER)
+        list(APPEND out_files "${CMAKE_CURRENT_BINARY_DIR}/${ARGS_GENERATE_HEADER}.h")
+        list(APPEND out_files "${CMAKE_CURRENT_BINARY_DIR}/${ARGS_GENERATE_HEADER}_internal.h")
+        list(APPEND header_arguments "--header=${ARGS_GENERATE_HEADER}.h")
+        list(APPEND header_arguments "--internal-header=${ARGS_GENERATE_HEADER}_internal.h")
+    endif(ARGS_GENERATE_HEADER)
+
+    add_custom_command(OUTPUT ${out_files} 
+    COMMAND 
+        ${VALA_EXECUTABLE} 
+    ARGS 
+        "-C" 
+        ${header_arguments} 
+        ${vapi_arguments}
+        "-b" ${CMAKE_CURRENT_SOURCE_DIR} 
+        "-d" ${CMAKE_CURRENT_BINARY_DIR} 
+        ${vala_pkg_opts} 
+        ${ARGS_OPTIONS} 
+        ${in_files} 
+        ${ARGS_CUSTOM_VAPIS}
+    DEPENDS 
+        ${in_files} 
+        ${ARGS_CUSTOM_VAPIS}
+    )
+endmacro(vala_precompile)
diff --git a/cmake/vala/ValaVersion.cmake b/cmake/vala/ValaVersion.cmake
new file mode 100644
index 0000000..fba9df6
--- /dev/null
+++ b/cmake/vala/ValaVersion.cmake
@@ -0,0 +1,96 @@
+##
+# Copyright 2009 Jakob Westhoff. All rights reserved.
+# 
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are met:
+# 
+#    1. Redistributions of source code must retain the above copyright notice,
+#       this list of conditions and the following disclaimer.
+# 
+#    2. Redistributions in binary form must reproduce the above copyright notice,
+#       this list of conditions and the following disclaimer in the documentation
+#       and/or other materials provided with the distribution.
+# 
+# THIS SOFTWARE IS PROVIDED BY JAKOB WESTHOFF ``AS IS'' AND ANY EXPRESS OR
+# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
+# MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO
+# EVENT SHALL JAKOB WESTHOFF OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+# PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+# LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE
+# OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+# 
+# The views and conclusions contained in the software and documentation are those
+# of the authors and should not be interpreted as representing official policies,
+# either expressed or implied, of Jakob Westhoff
+##
+
+include(ParseArguments)
+find_package(Vala REQUIRED)
+
+##
+# Ensure a certain valac version is available
+#
+# The initial argument is the version to check for
+# 
+# It may be followed by a optional parameter to specifiy a version range. The
+# following options are valid:
+# 
+# EXACT
+#   Vala needs to be available in the exact version given
+# 
+# MINIMUM
+#   The provided version is the minimum version. Therefore Vala needs to be
+#   available in the given version or any higher version
+#
+# MAXIMUM
+#   The provided version is the maximum. Therefore Vala needs to be available
+#   in the given version or any version older than this
+#
+# If no option is specified the version will be treated as a minimal version.
+##
+macro(ensure_vala_version version)
+    parse_arguments(ARGS "" "MINIMUM;MAXIMUM;EXACT" ${ARGN})
+	set(compare_message "")
+	set(error_message "")
+	if(ARGS_MINIMUM)
+		set(compare_message "a minimum ")
+		set(error_message "or greater ")
+	elseif(ARGS_MAXIMUM)
+		set(compare_message "a maximum ")
+		set(error_message "or less ")
+	endif(ARGS_MINIMUM)
+	
+	message(STATUS 
+		"checking for ${compare_message}Vala version of ${version}"
+	)
+
+	unset(version_accepted)
+	
+	# MINIMUM is the default if no option is specified
+	if(ARGS_EXACT)
+		if(${VALA_VERSION} VERSION_EQUAL ${version} )
+			set(version_accepted TRUE)	
+		endif(${VALA_VERSION} VERSION_EQUAL ${version})
+	elseif(ARGS_MAXIMUM)
+		if(${VALA_VERSION} VERSION_LESS ${version} OR ${VALA_VERSION} VERSION_EQUAL ${version})
+			set(version_accepted TRUE)	
+		endif(${VALA_VERSION} VERSION_LESS ${version} OR ${VALA_VERSION} VERSION_EQUAL ${version})
+	else(ARGS_MAXIMUM)
+		if(${VALA_VERSION} VERSION_GREATER ${version} OR ${VALA_VERSION} VERSION_EQUAL ${version})
+			set(version_accepted TRUE)	
+		endif(${VALA_VERSION} VERSION_GREATER ${version} OR ${VALA_VERSION} VERSION_EQUAL ${version})
+	endif(ARGS_EXACT)
+
+	if (NOT version_accepted)
+		message(FATAL_ERROR 
+			"Vala version ${version} ${error_message}is required."
+		)
+	endif(NOT version_accepted)
+
+	message(STATUS
+		"  found Vala, version ${VALA_VERSION}"
+	)
+endmacro(ensure_vala_version)
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
new file mode 100644
index 0000000..a725dd3
--- /dev/null
+++ b/src/CMakeLists.txt
@@ -0,0 +1,10 @@
+vala_precompile(EVA_C
+  Term.vala
+PACKAGES
+  gee-1.0
+  erl_interface
+GENERATE_VAPI
+  eva
+)
+
+add_library(eva SHARED ${EVA_C})
diff --git a/src/Term.vala b/src/Term.vala
new file mode 100644
index 0000000..2a9cca8
--- /dev/null
+++ b/src/Term.vala
@@ -0,0 +1,71 @@
+namespace Eva {
+  public interface Term : Object {
+    public abstract string to_string();
+    
+    public abstract void encode(Erl.Buffer buffer);
+  }
+  
+  public class Long : Object, Term {
+    public long value {get; construct;}
+    
+    public Long(long v) {
+      Object(value: v);
+    }
+    
+    public string to_string() {
+      return value.to_string();
+    }
+    
+    public void encode(Erl.Buffer buffer) {
+      buffer.encode_long(value);
+    }
+  }
+  
+  public class ULong : Object, Term {
+    public ulong value {get; construct;}
+    
+    public ULong(ulong v) {
+      Object(value: v);
+    }
+    
+    public string to_string() {
+      return value.to_string();
+    }
+    
+    public void encode(Erl.Buffer buffer) {
+      buffer.encode_ulong(value);
+    }
+  }
+  
+  public class Double : Object, Term {
+    public double value {get; construct;}
+    
+    public Double(double v) {
+      Object(value: v);
+    }
+    
+    public string to_string() {
+      return value.to_string();
+    }
+    
+    public void encode(Erl.Buffer buffer) {
+      buffer.encode_double(value);
+    }
+  }
+  
+  public class Atom : Object, Term {
+    public string value {get; construct;}
+    
+    public Atom(string v) {
+      Object(value: v);
+    }
+    
+    public string to_string() {
+      return value.to_string();
+    }
+    
+    public void encode(Erl.Buffer buffer) {
+      buffer.encode_atom(value.to_utf8());
+    }
+  }
+}
diff --git a/test/CMakeLists.txt b/test/CMakeLists.txt
new file mode 100644
index 0000000..2c11d3b
--- /dev/null
+++ b/test/CMakeLists.txt
@@ -0,0 +1,12 @@
+vala_precompile(TEST_C
+  Test.vala
+PACKAGES
+  gee-1.0
+  erl_interface
+CUSTOM_VAPIS
+  ${eva_BINARY_DIR}/src/eva.vapi
+)
+
+include_directories(BEFORE ${eva_BINARY_DIR}/src)
+add_executable(eva-test ${TEST_C})
+target_link_libraries(eva-test eva)
diff --git a/test/Test.vala b/test/Test.vala
new file mode 100644
index 0000000..ce5da6d
--- /dev/null
+++ b/test/Test.vala
@@ -0,0 +1,9 @@
+namespace Eva {
+  class Test {
+    public static int main(string[] args) {
+      Eva.Long term = new Eva.Long(42);
+      
+      return 0;
+    }
+  }
+}